Справочник функций

Ваш аккаунт

Войти через: 
Забыли пароль?
Регистрация
Информацию о новых материалах можно получать и без регистрации:

Последние темы форума

Показать новые сообщения »

Почтовая рассылка

Подписчиков: 11639
Последний выпуск: 19.06.2015

Оптимизация для pentium процессора - скоростные испытания

22. СКОРОСТНЫЕ ИСПЫТАНИЯ
========================
У Pentium есть внутренний, 64 битный таймер, который может быть прочитан в
EDX:EAX при использовании инструкции RDTSC (чтение временной счетчик). Это
очень полезно для замера точного количества тактов, потребовавшихся на
исполнение части кода.

Нижеприведенная программа замеряет количество тактов, которое исполнялась
часть кода. Программа выполняет 10 раз, 10 раз сохраняя время ушедшее на
исполнение кода. Программа может использоваться как в 16 так и в 32 битном
режиме.

RDTSC   MACRO                   ; макрос инструкции RDTSC
        DB      0FH,31H
ENDM

ITER    EQU     10              ; количество итераций

.DATA                           ; сегмент данных
ALIGN   4
COUNTER DD      0               ; счетчик цикла
TICS    DD      0               ; временное хранение счетчика таймера
RESULTLIST  DD  ITER DUP (0)    ; список результатов теста

.CODE                           ; сегмент кода
BEGIN:  MOV     [COUNTER],0     ; сброс счетчика цикла
TESTLOOP:                       ; проверка цикла
;****************   Делайте любую инициализацию здесь:   *******************
        FINIT
;****************   Конец инициализаций    *********************************
        RDTSC                   ; читаем счетчик таймера
        MOV     [TICS],EAX      ; сохраняем его
        CLD                     ; неспариваемый заполнитель
REPT    8
        NOP                     ; восемь NOP, для анулирования затеняющего
                                ; эффекта
ENDM

;****************   Впишите сюда тестируемые инструкции:  ******************
        FLDPI                   ; это только для примера
        FSQRT
        RCR     EBX,10
        FSTP    ST
;********************* Конец блока тестируемых инструкций  *****************

        CLC                     ; неспариваемый заполнитель с затенением
        RDTSC                   ; читаем таймер опять
        SUB     EAX,[TICS]      ; вычисляем разницу
        SUB     EAX,15          ; уменьшаем число тактов, ушедшие на заполниетль
        MOV     EDX,[COUNTER]   ; счетчик цикла
        MOV     [RESULTLIST][EDX],EAX   ; сохраняем результат в таблице
        ADD     EDX,TYPE RESULTLIST     ; увеличиваем счетчик
        MOV     [COUNTER],EDX           ; сохраняем счетчик таймера
        CMP     EDX,ITER * (TYPE RESULTLIST)
        JB      TESTLOOP                ; повторяем итерацию

; включите сюда код, для чтения результатов из таблицы RESULTLIST

Инструкция "заполнитель" устанавливается до и после критических частей кода.
Не спариваемая инструкция CLD включена, для того, что бы убедиться, что
спаривание и прочие эффекты идут как задумывалось. Восемь инструкций NOP
включены для защиты от декодирования префиксов и что бы тестовый код был
свободен от теней декодировки других инструкций. Однобайтные инструкции
включены здесь для сохранения условий спаривания. Инструкция CLC после
тестируемого кода включена для оттенения декодирования префикса 0FH инструкции
RDTSC, осовбождая тест от возможного затеняющего эффекта.

На PentiumPro вы можете использовать инструкцию CPUID до и после каждого
RDTSC, для того, что бы предотвратить параллельное исполнение вашего кода с
чем-нибудь еще. Декодирование CPUID на Pentium без MMX, из-за префикса 0FH,
но на него не распространяется затеняющий эффект, из-за того, что она
выполняется сериями.

Инструкция RDTSC не может выполняться в режиме виртуального 8086, так если
вы запускаете эту программу под DOS вы должны закомментировать EMM386 (или
любой друго менеджер памяти) в CONFIG.SYS и не запускать программу в DOS окне
под Windows.

У Pentium процессоров есть специальные счетчики монитора производительности,
с помощью которых вы можете просчитать такие вещи, как промахи кеша,
рассогласование, остановки AGI, и т.д. Подробное руководство, как пользоваться
этими счетчиками, не описано в этом руководстве, и может быть найдено
где-нибудь еще.

Оставить комментарий

Комментарий:
можно использовать BB-коды
Максимальная длина комментария - 4000 символов.
 
Реклама на сайте | Обмен ссылками | Ссылки | Экспорт (RSS) | Контакты
Добавить статью | Добавить исходник | Добавить хостинг-провайдера | Добавить сайт в каталог